//Definition für Harvard, Nachname zuerst
//N. Busch 30.04.2009
//Anpassung an Empfehlungen Schreibberatung PH FHNW
//Res Mezger 05.08.2009
//Typ: Titel

Let(
[$Periodikum = 
   Case( DGlobals::d_SigleBenutzen_n = 1 and not IsEmpty( DTitel.Periodikum::d_Sigle_t );
             DTitel.Periodikum::d_Sigle_t;
         DTitel.Periodikum::d_Titel_t );

 $HerausgeberStatus =
     Case(  IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n <> 1 ; 0; 
                IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n = 1 ; 1 ;
                not IsEmpty( d_HerausgeberName_t) and IsEmpty(d_AutorNachname_t); 2;
                not IsEmpty( d_HerausgeberName_t) and not IsEmpty(d_AutorNachname_t); 3) ;
     
 $AutorPerson = 
    Trim( d_AutorNachname_t & Case( not IsEmpty( d_AutorVorname_t ) ; ", " &
          d_AutorVorname_t ) & xcalc_Pseudonym_ctu ) ;

 $Coautoren =

    Trim(Case(
               not IsEmpty( xCalc_NamenCoautorenNV_ctu) ;
                  DGlobals::d_Coautortrenner_t & xCalc_NamenCoautorenNV_ctu ;
               not IsEmpty( d_CoAutoren_t ) ;
                  "; " & d_CoAutoren_t 
          )) ;

 $CoautorenSB =
          Trim(Case(
               not IsEmpty( DTitel.Titel.Sammelband::xCalc_NamenCoautorenNV_ctu) ;
                  DGlobals::d_Coautortrenner_t & DTitel.Titel.Sammelband::xCalc_NamenCoautorenNV_ctu ;
               not IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ;
                  "; " & DTitel.Titel.Sammelband::d_CoAutoren_t 
          ));

 $Autor =
    Case( 
       $Herausgeberstatus = 0;
            $Autorperson &
            $Coautoren;

       $Herausgeberstatus = 1;
            $Autorperson &
            $Coautoren & 
            " (" & DGlobals::d_HerausgeberKürzel_t & ")"   ;

       $Herausgeberstatus = 2;
            d_HerausgeberName_t & " (" & DGlobals::d_HerausgeberKürzel_t & ")" ;

       $Herausgeberstatus = 3;
            $Autorperson &
            $Coautoren

             ;
     ) // end case
]
;

Case(
   d_Datentyp2_t = "Artikel";

     // Zitform für Artikel

     Trim( 
      $Autor & 
      Case(not IsEmpty(d_Datierung_t) ; " (" & d_Datierung_t ) &
      "): " & TextStyleAdd( d_Titel_t; Italic ) & ". In: " &
      DTitel.Periodikum::d_Titel_t &
      Case( not IsEmpty(  d_AusgabeVol_t); " " ) & d_AusgabeVol_t &
      Case( not IsEmpty(  d_AusgabeNr_t ); ", Heft " & d_AusgabeNr_t ) &  
      Case( not IsEmpty(  d_AusgabeSeite_t) ; ". S. " & d_AusgabeSeite_t ) & "." &
      Case( not IsEmpty(  d_URL_t) ; " [" & d_URL_t & "].")
      ) // End trim
   ;
   d_Datentyp2_t = "Aufsatz";

     // Zitform für Aufsätze

      Trim( 
      $Autor & 
      Case(not IsEmpty(d_Datierung_t) ; " (" & d_Datierung_t ) &
      "): " & TextStyleAdd( d_Titel_t; Italic ) & ". In: " &
      DTitel.Titel.Sammelband::xCalc_NameAutorKomplett_cti & 
      $CoautorenSB &
      case( DTitel.Titel.Sammelband::d_Herausgeber_n = 1 ; " (Hg.), " ; ", " ) &
       TextStyleAdd( DTitel.Titel.Sammelband::d_Titel_t ; Italic ) & ", " & 
      Case( not IsEmpty(  DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &  
      Case( not IsEmpty(  DTitel.Titel.Sammelband::d_Ort_t ) and not IsEmpty( DTitel.Titel.Sammelband::d_Verlag_t ) ; ": ") & 
      Case( not IsEmpty( DTitel.Titel.Sammelband::d_Verlag_t ) ; DTitel.Titel.Sammelband::d_Verlag_t ) & 
      Case( not IsEmpty(  d_AusgabeSeite_t ) ; ". S." & d_AusgabeSeite_t ) & "." &
      Case( not IsEmpty(  d_Reihe_t ) ; " (= " & d_Reihe_t & ").") 
      ) // End trim
   ;

   d_Datentyp2_t = "Vortrag";

     // Zitform für Vorträge

      Trim( 
      $Autor & 
      Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " & DTitel.Titel.Sammelband::d_Datierung_t )  &
      ": " & Quote( d_Titel_t )  & ", lecture, " &
      "" & TextStyleAdd( DTitel.Titel.Sammelband::d_Titel_t ; Italic )  & ", " & 
      Case( not IsEmpty(  DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) 
      ) // End trim
   ;

   d_Datentyp2_t = "Tagung";

   // Zitform für Tagungen

      Trim( 
      "Tagung " & 
      Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " & DTitel.Titel.Sammelband::d_Datierung_t )  &
      " " & TextStyleAdd( d_Titel_t ; Italic )  & "" &
      Case( not IsEmpty(  d_Körperschaft_t ); ", " & d_Körperschaft_t ) &  
      Case( not IsEmpty( d_Ort_t ) ; ", " & d_Ort_t ) 
      ) // End trim
   ;
   // Zitform für Monographien   

   Trim( 
      $Autor &
      Case( not IsEmpty( d_Datierung_t ) or not isempty(d_Auflage_t) ; "" ) &
      Case( not IsEmpty( d_Auflage_t ) ;  d_Auflage_t & ". Hrsg. " )  & " (" &d_Datierung_t  & "): " & 
      TextStyleAdd( d_Titel_t ; Italic) & 
      Case( $HerausgeberStatus = 3 ; ". Hrsg. v. " & d_HerausgeberName_t) &
      Case( not IsEmpty(  d_Ort_t ) and not IsEmpty( d_Verlag_t ) ; ". ") & 
      Case( not IsEmpty(  d_Ort_t ); d_Ort_t ) &  
      Case( not IsEmpty( d_Verlag_t ) ; ": " & d_Verlag_t ) &
      "." &
      Case( not IsEmpty(  d_Reihe_t ) ; " (= " & d_Reihe_t & ").") &
      Case( not IsEmpty(  d_BibliogrZusätze_t ) ; " (" & d_BibliogrZusätze_t & ")") &
      Case( not IsEmpty( DTitel.Titel.Sammelband::_pk_GUID );
       " [" &  Trim( DTitel.Titel.Sammelband::d_Kurztitel_t & " " & d_AusgabeVol_t & 
       Case(not IsEmpty( d_AusgabeVol_t ) and not IsEmpty(d_AusgabeNr_t) ; "/" ) & d_AusgabeNr_t) 
            & "]"
     ) //end case
   ) // End trim
) //End Case

& DGlobals::v_ZitformSchlusszeichen
)